Make sure the databases are being backed up

Making sure the databases are being backed up is the first check every DBA needs to do. Following is the script to check the the last date of the database backup on current server or list out the databases which were not not backed up within last X number of days. It will also include databases which were never backed up on current server. It works with SQL Server version 2005 and above.

--//-------------------------------------//-- 
--// Credits http://sqlgear.blogspot.com //--
--//-------------------------------------//--
/* 
Finding last backup date for all the databases
OR find the databases not backed up within last X number of days.
*/
DECLARE @Days AS INT

SET @Days = 0 --//If Set to 0 it will show you the last backup dates for the databases

SELECT 'Database ' + d.NAME + ' was ' + CASE MAX(ISNULL(b.backup_finish_date, '1900-01-01 00:00:00.000'))
  WHEN '1900-01-01 00:00:00.000'
   THEN ' never backedup.'
  ELSE 'last backed up on ' + CAST(MAX(ISNULL(b.backup_finish_date, '1900-01-01 00:00:00.000')) AS VARCHAR(200))
  END AS [Message]
FROM master.sys.databases d
LEFT OUTER JOIN msdb.dbo.backupset b ON d.NAME = b.database_name
 AND b.type = 'D'
 AND b.server_name = SERVERPROPERTY('ServerName') --//Last server backup is current server
WHERE d.database_id <> 2 --//Ignoring tempdb
 AND d.STATE <> 1 --//Not in restoring state
 AND d.is_in_standby = 0 --//Not in standby state
 AND d.source_database_id IS NULL --//Ignoring database snapshots
GROUP BY d.NAME
HAVING DATEADD(dd, (- 1 * @Days), GETDATE()) >= MAX(ISNULL(b.backup_finish_date, '1900-01-01 00:00:00.000'))