Download RDLs in same folder structure as on ReportServer

I frequently get request to provide RDLs to developer teams. They do have repository for most of the servers but for those servers which do not have any repository and you need to download RDLs from certain folder it get tedious if there are numerous reports under a folder and its sub folder. The below query will download reports under each folder and subfolder and create same folder structure in the mentioned download folder on the ReportServer.
Note: xp_cmdshell should be enabled on the server.

     
--//-- www.SQLGear.net --//--
DECLARE @FullDirectoryPathStatement AS VARCHAR(500) = 'C:\DownloadReport\'

SET @FullDirectoryPathStatement = LTRIM(RTRIM(@FullDirectoryPathStatement))

IF RIGHT(@FullDirectoryPathStatement, 1) = '\'
 SET @FullDirectoryPathStatement = SUBSTRING(@FullDirectoryPathStatement, 1, LEN(@FullDirectoryPathStatement) - 1)

DECLARE @FilterReportPath AS VARCHAR(500) = NULL
DECLARE @SSRSFolderPath NVARCHAR(850);
DECLARE @SSRSFolder NVARCHAR(850);
DECLARE @Exists SMALLINT = 0
DECLARE @SqlScript NVARCHAR(MAX)
DECLARE @TSQL AS NVARCHAR(MAX) = ''
DECLARE @FilterReportName AS VARCHAR(500) = 'Test Report Folder' --// If NULL it will download all RDLs
DECLARE @OutputPath AS VARCHAR(500)

IF LTRIM(RTRIM(ISNULL(@FullDirectoryPathStatement, ''))) = ''
BEGIN
 SELECT 'Invalid Output Path'
END
ELSE
BEGIN
 IF OBJECT_ID('Tempdb..#DirectoryExists') IS NOT NULL
  DROP TABLE #DirectoryExists

 CREATE TABLE #DirectoryExists (IsValid VARCHAR(MAX))

 --//Cursor for each SSRS folder and subfolder for given folder
 DECLARE SSRSFolder_cursor CURSOR
 FOR
 SELECT Path
 FROM ReportServer.dbo.CATALOG CL
 WHERE CL.[Type] = 1
  AND Path LIKE '/' + ISNULL(@FilterReportPath, '') + '%'
 FOR READ ONLY

 OPEN SSRSFolder_cursor

 FETCH NEXT
 FROM SSRSFolder_cursor
 INTO @SSRSFolder

 WHILE @@FETCH_STATUS = 0
 BEGIN
  --//Create the folder if does not exist
  SET @SSRSFolderPath = REPLACE(@SSRSFolderPath, '/', '\')
  SET @SSRSFolderPath = 'DIR "' + @FullDirectoryPathStatement + @SSRSFolder + '" /B'

  INSERT INTO #DirectoryExists
  EXEC xp_cmdshell @SSRSFolderPath

  SELECT @Exists = (
    SELECT COUNT(IsValid)
    FROM #DirectoryExists
    WHERE IsValid <> 'File Not Found'
     AND IsValid IS NOT NULL
    )

  IF @Exists = 0
  BEGIN
   SET @SqlScript = 'EXEC master.dbo.xp_cmdshell ''mkDir "' + @FullDirectoryPathStatement + REPLACE(@SSRSFolder, '/', '\') + '"'''

   EXEC sp_executesql @SqlScript
  END

  --//Fetch the RDL file
  SET @OutputPath = REPLACE(@FullDirectoryPathStatement, '\', '/') + @SSRSFolder + '/'
  SET @TSQL = STUFF((
     SELECT ';EXEC master..xp_cmdshell ''bcp " ' + ' SELECT ' + ' CONVERT(VARCHAR(MAX), ' + '       CASE ' + '         WHEN LEFT(C.Content,3) = 0xEFBBBF THEN STUFF(C.Content,1,3,'''''''') ' + '         ELSE C.Content ' + '       END) ' + ' FROM ' + ' [ReportServer].[dbo].[Catalog] CL ' + ' CROSS APPLY (SELECT CONVERT(VARBINARY(MAX),CL.Content) Content) C ' + ' WHERE ' + ' CL.ItemID = ''''' + CONVERT(VARCHAR(MAX), CL.ItemID) + ''''' " queryout "' + @OutputPath + '' + CL.NAME + '.rdl" ' + '-T -c -x'''
     FROM [ReportServer].[dbo].[Catalog] CL
     WHERE CL.[Type] = 2 --Report
      AND '/' + CL.[Path] + '/' LIKE COALESCE('%/%' + @SSRSFolder + '%/%', '/' + CL.[Path] + '/')
      AND LEN(CL.[Name]) = LEN(CL.[Path]) - LEN(@SSRSFolder) - 1
      AND CL.NAME LIKE COALESCE('%' + @FilterReportName + '%', CL.NAME)
     FOR XML PATH('')
     ), 1, 1, '')

  EXEC SP_EXECUTESQL @TSQL

  DELETE
  FROM #DirectoryExists

  FETCH NEXT
  FROM SSRSFolder_cursor
  INTO @SSRSFolder
 END

 CLOSE SSRSFolder_cursor;

 DEALLOCATE SSRSFolder_cursor;

 DROP TABLE #DirectoryExists
END